blob: a2e97e5cf555afc59bde3f91475ad6ff8805aca3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 205075 2014-02-04 11:31:25Z heftig $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: kevin <kevin@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
pkgname=graphviz
pkgver=2.36.0
pkgrel=2
pkgdesc='Graph visualization software'
url='http://www.graphviz.org/'
license=('CPL')
arch=('i686' 'x86_64')
depends=('libltdl' 'gd' 'librsvg' 'libxaw' 'ghostscript' 'pango' 'gts')
makedepends=('swig' 'mono' 'guile' 'lua51' 'ocaml' 'perl' 'php' 'python2' 'r' 'tk' 'qt4' 'gtk2')
optdepends=('mono: sharp bindings'
'guile: guile bindings'
'lua51: lua bindings'
'ocaml: ocaml bindings'
'perl: perl bindings'
'php: php bindings'
'python2: python bindings'
'r: r bindings'
'tcl: tcl bindings'
'qt4: gvedit'
'gtk2: gtk output plugin')
source=("${url}/pub/${pkgname}/stable/SOURCES/${pkgname}-${pkgver}.tar.gz")
sha1sums=('a41e9f1cbcc9a24651e14dd15a4cda3d912d7d19')
install=install
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export LIBPOSTFIX=/
export PYTHON=python2
export LUA=lua5.1
./configure --prefix=/usr
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# Workaround symlink upgrade bug (fixed in pacman trunk)
# Also deduplicates the tcl libraries (upstream bug?)
# Might have been this commit: https://github.com/ellson/graphviz/commit/f11aead
rm -r "${pkgdir}/usr/lib/tcl8.6/graphviz"
ln -s ../graphviz/tcl "$pkgdir/usr/lib/tcl8.6/graphviz"
}
|
