blob: 35e682bfc8e05923ff3817db07ff3f30a1638416 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 203291 2014-01-07 13:07:33Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gst-libav
pkgver=1.2.2
pkgrel=1
pkgdesc="Gstreamer libav Plugin"
arch=('i686' 'x86_64')
license=('GPL')
url="http://gstreamer.freedesktop.org/"
depends=('gst-plugins-base-libs' 'bzip2')
makedepends=('yasm' 'python')
options=(!emptydirs)
provides=("gst-ffmpeg=$pkgver-$pkgrel")
source=(${url}/src/$pkgname/$pkgname-$pkgver.tar.xz)
sha256sums=('585eb7971006100ad771a852e07bd2f3e23bcc6eb0b1253a40b5a0e40e4e7418')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-static --with-libav-extra-configure="--enable-runtime-cpudetect" \
--with-package-name="GStreamer libav Plugin (Arch Linux)" \
--with-package-origin="http://www.archlinux.org/"
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="${pkgdir}" install
}
|
