blob: 33e97061716b2c2187fde024a609f7759debe1fe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 198086 2013-10-30 12:43:06Z allan $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: tobias <tobias funnychar archlinux.org>
pkgbase=gtk-xfce-engine
pkgname=('gtk2-xfce-engine' 'gtk3-xfce-engine')
pkgver=3.0.1
pkgrel=1
arch=('i686' 'x86_64' 'mips64el')
url="http://www.xfce.org/"
license=('GPL2')
groups=('xfce4')
makedepends=('gtk2' 'gtk3')
source=(http://archive.xfce.org/src/xfce/$pkgbase/3.0/$pkgbase-$pkgver.tar.bz2)
sha256sums=('eb03cf81da1a91e426a2141c092ed7a1634cab29ea2f3546480e901290a7a06d')
build() {
cd "$srcdir/$pkgbase-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib \
--localstatedir=/var \
--disable-static \
--disable-debug
make
}
package_gtk2-xfce-engine() {
pkgdesc="Xfce Gtk+-2.0 engine"
depends=('gtk2')
provides=("gtk-xfce-engine=$pkgver-$pkgrel")
conflicts=('gtk-xfce-engine')
replaces=('gtk-xfce-engine')
cd "$srcdir/$pkgbase-$pkgver"
make DESTDIR="$pkgdir" install
# Remove gtk3 engine and themes
find "$pkgdir" -name gtk-3.0 -exec rm -r {} +
}
package_gtk3-xfce-engine() {
pkgdesc="Xfce Gtk+-3.0 engine"
depends=('gtk3')
conflicts=('gtk-xfce-engine<=2.99.0-1')
cd "$srcdir/$pkgbase-$pkgver"
make DESTDIR="$pkgdir" install
# Remove gtk2 engine and themes
find "$pkgdir" -name gtk-2.0 -exec rm -r {} +
}
# vim:set ts=2 sw=2 et:
|
