blob: be7d4a14bd09a2a3e465c09325e7a5cc693a23b5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 165858 2012-09-01 17:47:38Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=gtkmm3
_pkgbasename=gtkmm
pkgname=('gtkmm3' 'gtkmm3-docs')
pkgver=3.4.1
pkgrel=1
arch=('i686' 'x86_64')
makedepends=('gtk3' 'pangomm' 'atkmm' 'glibmm-docs' 'mm-common' 'doxygen' 'libxslt')
license=('LGPL')
options=('!libtool' '!emptydirs')
url="http://www.gtkmm.org/"
source=(http://ftp.gnome.org/pub/GNOME/sources/$_pkgbasename/${pkgver%.*}/$_pkgbasename-$pkgver.tar.xz)
sha256sums=('af218681c8ba7b97cafa67419d43be8d1151a541c1aea2a20d76971ef487bdcf')
build() {
cd "$_pkgbasename-$pkgver"
./configure --prefix=/usr
make
}
package_gtkmm3() {
pkgdesc="C++ bindings for gtk3"
depends=('gtk3' 'pangomm' 'atkmm')
cd "$_pkgbasename-$pkgver"
sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
make DESTDIR="$pkgdir" install
}
package_gtkmm3-docs() {
pkgdesc="Developer documentation for gtkmm v3"
cd "$_pkgbasename-$pkgver"
make -C docs DESTDIR="$pkgdir" install
}
|
