blob: 46a64a40292637f8a89bea6c6f00eb0c68eaef66 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 196332 2013-10-11 14:56:43Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=gtkmm3
_pkgbasename=gtkmm
pkgname=('gtkmm3' 'gtkmm3-docs')
pkgver=3.10.0
pkgrel=1
arch=('i686' 'x86_64')
makedepends=('gtk3' 'pangomm' 'atkmm' 'glibmm-docs' 'mm-common' 'doxygen' 'libxslt')
license=('LGPL')
options=('!libtool' '!emptydirs')
url="http://www.gtkmm.org/"
source=(http://ftp.gnome.org/pub/GNOME/sources/$_pkgbasename/${pkgver%.*}/$_pkgbasename-$pkgver.tar.xz)
sha256sums=('5e45fed4a7cff1baa72d1ef67e0d9883063d3a575cb53190e7ecf27047d241f8')
build() {
cd "$_pkgbasename-$pkgver"
./configure --prefix=/usr
make
}
package_gtkmm3() {
pkgdesc="C++ bindings for gtk3"
depends=('gtk3' 'pangomm' 'atkmm')
cd "$_pkgbasename-$pkgver"
sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
make DESTDIR="$pkgdir" install
}
package_gtkmm3-docs() {
pkgdesc="Developer documentation for gtkmm v3"
cd "$_pkgbasename-$pkgver"
make -C docs DESTDIR="$pkgdir" install
}
|
