blob: ee811c27ed7a14ca5afa0d0b061769e18bb497cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 200683 2013-12-02 11:18:15Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=(harfbuzz)
pkgname=(harfbuzz harfbuzz-icu)
pkgver=0.9.24
pkgrel=1
pkgdesc="OpenType text shaping engine"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.freedesktop.org/wiki/Software/HarfBuzz"
license=(MIT)
makedepends=(glib2 freetype2 graphite cairo icu gobject-introspection)
source=(http://www.freedesktop.org/software/harfbuzz/release/${pkgbase}-${pkgver}.tar.bz2)
sha256sums=('edf25dd8a318acdeacd2aeade2387db23c109fec0da626f2127f43917a372422')
build() {
cd $pkgbase-$pkgver
./configure --prefix=/usr \
--with-glib --with-freetype --with-cairo --with-icu --with-graphite2 \
--with-gobject
make
}
package_harfbuzz() {
depends=(glib2 freetype2 graphite)
optdepends=('cairo: hb-view program')
cd $pkgbase-$pkgver
make DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/harfbuzz/COPYING"
# Split harfbuzz-icu
mkdir -p ../hb-icu/usr/{include/harfbuzz,lib/pkgconfig}; cd ../hb-icu
mv "$pkgdir"/usr/lib/libharfbuzz-icu* ./usr/lib
mv "$pkgdir"/usr/lib/pkgconfig/harfbuzz-icu.pc ./usr/lib/pkgconfig
mv "$pkgdir"/usr/include/harfbuzz/hb-icu.h ./usr/include/harfbuzz
}
package_harfbuzz-icu(){
pkgdesc="$pkgdesc (ICU integration)"
depends=(harfbuzz icu)
mv hb-icu/* "$pkgdir"
install -Dm644 $pkgbase-$pkgver/COPYING "$pkgdir/usr/share/licenses/harfbuzz-icu/COPYING"
}
|
