blob: 09b69a401216ee26549f2314fe0f2dd1d174dd78 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 148786 2012-02-05 11:50:28Z ibiru $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=imlib
pkgver=1.9.15
pkgrel=11
pkgdesc="General image handling library for X11 and Gtk"
arch=('i686' 'x86_64' 'mips64el')
url="http://freshmeat.net/projects/imlib/"
license=('GPL')
depends=('gtk' 'giflib' 'libpng' 'libtiff')
makedepends=('libxt')
options=('!libtool')
source=(http://ftp.gnome.org/pub/GNOME/sources/imlib/1.9/${pkgname}-${pkgver}.tar.bz2
debian-bug448360.patch CAN-2004-1026.patch aclocal-fixes.patch imlib-1.9.15-libpng15.patch)
sha1sums=('c9a732a354fbb3c7e1a426e5d19fc92d73f8f720'
'fe2fd9ce4d7bc62271e724153de39012de8ec5ee'
'ec1b47281c1a7fb21abe841f948ecc56ed13f310'
'af54cb1ee0c8c6122b277284ebdd1022e31df3b5'
'33c3aaa43eb624f2a6ab0406285a8515903333e3')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i "${srcdir}/debian-bug448360.patch"
patch -p1 -i "${srcdir}/CAN-2004-1026.patch"
patch -p0 -i "${srcdir}/aclocal-fixes.patch"
patch -p0 -i "${srcdir}/imlib-1.9.15-libpng15.patch"
sed '/AC_PATH_XTRA/d' -i configure.in
libtoolize --force
cp /usr/bin/libtool .
autoreconf --force --install
./configure --prefix=/usr --sysconfdir=/etc --mandir=/usr/share/man --enable-shm --disable-static
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
