blob: 716c0315f4dcf1bf7bd949304c5d8d2c9de9c1c7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 198861 2013-11-05 19:52:14Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
pkgbase=kdebindings-kross
pkgname=('kdebindings-kross-python'
# 'kdebindings-kross-ruby'
'kdebindings-kross-java')
pkgver=4.11.3
pkgrel=1
url="https://projects.kde.org/projects/kde/kdebindings/kross-interpreters"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
groups=('kdebindings')
makedepends=('kdelibs' 'cmake' 'automoc4' 'python2' 'java-environment')
source=("http://download.kde.org/stable/${pkgver}/src/kross-interpreters-${pkgver}.tar.xz")
sha1sums=('1e3af7d4f43ff744e64c7dc24677feeddcb9384c')
build() {
cd "${srcdir}"
mkdir build
cd build
cmake ../kross-interpreters-${pkgver} \
-DCMAKE_BUILD_TYPE=Release \
-DKDE4_BUILD_TESTS=OFF \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_ruby=OFF \
-DPYTHON_EXECUTABLE=/usr/bin/python2
make
}
package_kdebindings-kross-python() {
pkgdesc="Python2 language interpreters to enable in-process scripting with Kross"
depends=('kdelibs' 'python2')
cd "${srcdir}"/build/python
make DESTDIR="${pkgdir}" install
}
package_kdebindings-kross-java() {
pkgdesc="Java language interpreters to enable in-process scripting with Kross"
depends=('kdelibs' 'java-environment')
cd "${srcdir}"/build/java
make DESTDIR="${pkgdir}" install
}
package_kdebindings-kross-ruby() {
pkgdesc="Ruby language interpreters to enable in-process scripting with Kross"
depends=('kdelibs' 'ruby')
cd "${srcdir}"/build/ruby
make DESTDIR="${pkgdir}" install
}
|
