blob: 89c368a3645225d636a37e6afb93c288dfbb027c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 191925 2013-08-01 06:59:55Z bpiotrowski $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jon Nordby <jononor@gmail.com>
pkgname=libwebp
pkgver=0.3.1
pkgrel=3
pkgdesc="WebP library and conversion tools"
arch=('x86_64' 'i686' 'mips64el')
url="https://developers.google.com/speed/webp/"
license=(BSD)
depends=(libpng libjpeg libtiff giflib)
makedepends=(freeglut mesa glu)
optdepends=('freeglut: vwebp viewer')
options=('!libtool')
source=("http://webp.googlecode.com/files/$pkgname-$pkgver.tar.gz")
sha256sums=('b37932c625322a69fe4e9b88884b5c7aed2b3eaf9fd5e5b480aee339a92e6ee7')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure --prefix=/usr \
--enable-swap-16bit-csp \
--enable-experimental \
--enable-libwebpmux \
--enable-libwebpdemux \
--enable-libwebpdecoder \
--disable-static
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|
