blob: 86d18e87e4f28e0412126d19bacde861a9ecef7c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 169079 2012-10-17 18:31:25Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Gilles CHAUVIN <gcnweb@gmail.com>
pkgname=live-media
pkgver=2012.10.17
pkgrel=1
pkgdesc="A set of C++ libraries for multimedia streaming"
arch=('i686' 'x86_64' 'mips64el')
license=('LGPL')
url="http://live555.com/liveMedia"
depends=('gcc-libs')
source=("http://live555.com/liveMedia/public/live.${pkgver}.tar.gz")
md5sums=('c9319c87a768c01f8007965db5453ca1')
build() {
cd ${srcdir}/live
sed \
-e 's/$(INCLUDES) -I. -O2 -DSOCKLEN_T/$(INCLUDES) -I. -O2 -I. -fPIC -DRTSPCLIENT_SYNCHRONOUS_INTERFACE=1 -DSOCKLEN_T/g' \
-e 's/\(LIBRARY_LINK =\).*/\1 $(LD) -o/g' \
-e 's/\(LIBRARY_LINK_OPTS =\).*/\1 $(LINK_OPTS) -r -Bstatic/g' \
-i config.linux
./genMakefiles linux
make
}
package() {
cd ${srcdir}/live
for dir in BasicUsageEnvironment groupsock liveMedia UsageEnvironment; do
install -dm755 ${pkgdir}/usr/{bin,lib,include/${dir}}
install -m644 ${dir}/*.a "${pkgdir}/usr/lib"
install -m644 ${dir}/include/*.h* "${pkgdir}/usr/include/${dir}"
done
for testprog in `find testProgs -type f -perm 755`; do
install ${testprog} "${pkgdir}/usr/bin"
done
}
|
