blob: a75c633b54f4473c254cacc5ffee96c859f37559 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 185203 2013-05-12 06:52:48Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=lm_sensors
pkgver=3.3.3
pkgrel=3
pkgdesc="Collection of user space tools for general SMBus access and hardware monitoring"
arch=('i686' 'x86_64')
url="http://www.lm-sensors.org/"
license=('GPL' 'LGPL')
depends=('perl' 'sysfsutils')
makedepends=('rrdtool')
optdepends=('rrdtool: for logging with sensord')
backup=('etc/sensors3.conf' 'etc/healthd.conf')
options=('!emptydirs')
source=(http://dl.lm-sensors.org/lm-sensors/releases/lm_sensors-${pkgver}.tar.bz2{,.sig} \
healthd healthd.conf fancontrol.service sensord.service healthd.service \
linux_3.0.patch lm_sensors-fancontrol.patch)
sha1sums=('b55c06f425993e42f13553f204066c446da36fd3'
'SKIP'
'1c91ae403d3cd02b6177ad1f1b2f2c3a7a3257f5'
'6c4e8a2d89dd2fd3ca2f0f4f3b1230111e01b0fc'
'73cd658f4a418197dc75f65d6d309701c72cfd81'
'cea1ff07374a784cc4be1d28dc6c80641fcae99d'
'd72ec328e9303acef86342483b6f8537de6117d9'
'5662828085cdd981f0dc7cf8f79d3d6e2b72f50c'
'd3e419b4019451fb039ae3d3b8e0ec55121b9f17')
prepare() {
cd ${pkgname}-${pkgver}
sed -i 's|/etc/sysconfig|/etc/conf.d|' prog/{detect/sensors-detect,init/lm_sensors.service}
sed -i 's@\(/bin/systemctl\|/lib/systemd/system\)@/usr\1@g' prog/detect/sensors-detect
sed -i 's/EnvironmentFile=/EnvironmentFile=-/' prog/init/lm_sensors.service
patch -p0 -i "${srcdir}/linux_3.0.patch"
patch -p0 -i "${srcdir}/lm_sensors-fancontrol.patch"
}
build() {
cd ${pkgname}-${pkgver}
make PREFIX=/usr
}
package() {
cd ${pkgname}-${pkgver}
make PROG_EXTRA=sensord BUILD_STATIC_LIB=0 \
PREFIX=/usr SBINDIR=/usr/bin MANDIR=/usr/share/man DESTDIR="${pkgdir}" install
install -D -m644 prog/init/lm_sensors.service "${pkgdir}/usr/lib/systemd/system/lm_sensors.service"
install -D -m755 "${srcdir}/healthd" "${pkgdir}/usr/bin/healthd"
install -D -m644 "${srcdir}/healthd.conf" "${pkgdir}/etc/healthd.conf"
install -D -m644 "${srcdir}/fancontrol.service" "${pkgdir}/usr/lib/systemd/system/fancontrol.service"
install -D -m644 "${srcdir}/sensord.service" "${pkgdir}/usr/lib/systemd/system/sensord.service"
install -D -m644 "${srcdir}/healthd.service" "${pkgdir}/usr/lib/systemd/system/healthd.service"
}
|
