blob: 28a98b68e1e07b032d6c5f5d8438b3cf11a108de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 205937 2014-02-14 10:21:00Z juergen $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Damir Perisa <damir@archlinux.org>
pkgname=maxima
pkgver=5.32.1
pkgrel=2
pkgdesc="A sophisticated computer algebra system"
arch=('i686' 'x86_64')
license=('GPL')
url="http://maxima.sourceforge.net"
depends=('sbcl=1.1.15' 'texinfo' 'sh')
makedepends=('python2')
optdepends=('gnuplot: plotting capabilities' 'rlwrap: readline support via /usr/bin/rmaxima' 'tk: graphical xmaxima interface')
# needs rebuild when bash changes version
# needs a rebuild when sbcl changes version
options=('!makeflags' '!zipman') # don't zip info pages or they won't work inside maxima
install=maxima.install
source=("http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz" "$pkgname.desktop")
sha1sums=('8667c9e26fdb2889ceb0641b0abc7372aadd591a'
'4398ebb1ec85ccfa12f37516a56d60c26f74b18b')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# set correct python executable to create docs
sed -i "s|${PYTHONBIN:-python}|python2|" doc/info/extract_categories.sh
./configure --prefix=/usr --mandir=/usr/share/man --infodir=/usr/share/info \
--libexecdir=/usr/lib --enable-sbcl --with-default-lisp=sbcl
# help avoid (re)running makeinfo/tex
touch doc/info/maxima.info
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# install some freedesktop.org compatibility
install -Dm644 "${srcdir}/${pkgname}.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
# make sure, we have a nice icon for the desktop file at the right place ;)
install -d "${pkgdir}/usr/share/pixmaps/"
ln -s /usr/share/maxima/${pkgver}/xmaxima/maxima-new.png \
"${pkgdir}/usr/share/pixmaps/${pkgname}.png"
}
|
