blob: f648b4e6235947cafc64445032615741e8314e43 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 178301 2013-02-19 19:05:06Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Damir Perisa <damir@archlinux.org>
pkgname=maxima
pkgver=5.29.1
pkgrel=1
pkgdesc="Maxima - a sophisticated computer algebra system"
arch=('i686' 'x86_64')
license=('GPL')
url="http://maxima.sourceforge.net"
depends=('sbcl=1.1.4' 'texinfo' 'sh')
makedepends=('python2')
optdepends=('gnuplot: plotting capabilities' 'rlwrap: readline support via /usr/bin/rmaxima' 'tk: graphical xmaxima interface')
# needs rebuild when bash changes version
# needs a rebuild when sbcl changes version
options=('!makeflags' '!zipman') # don't zip info pages or they won't work inside maxima
install=maxima.install
source=("http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz" "$pkgname.desktop")
sha1sums=('9be04303d6a5472bc95576b7de7286fa4b8ff604'
'4398ebb1ec85ccfa12f37516a56d60c26f74b18b')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
# set correct python executable to create docs
sed -i "s|${PYTHONBIN:-python}|python2|" doc/info/extract_categories.sh
./configure --prefix=/usr --mandir=/usr/share/man --infodir=/usr/share/info \
--libexecdir=/usr/lib --enable-sbcl --with-default-lisp=sbcl
make
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
# install some freedesktop.org compatibility
install -Dm644 ${srcdir}/${pkgname}.desktop \
${pkgdir}/usr/share/applications/${pkgname}.desktop
# make sure, we have a nice icon for the desktop file at the right place ;)
install -d ${pkgdir}/usr/share/pixmaps/
ln -s /usr/share/maxima/${pkgver}/xmaxima/maxima-new.png \
${pkgdir}/usr/share/pixmaps/${pkgname}.png
}
|
