blob: 295a871af8402f6ed464a25c10dad187a4b2251a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# $Id: PKGBUILD 179309 2013-03-05 11:03:53Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>
# Contributor: Ben <ben@benmazer.net>
pkgname=mpd
pkgver=0.17.3
pkgrel=3
pkgdesc='Flexible, powerful, server-side application for playing music'
url='http://mpd.wikia.com/wiki/Music_Player_Daemon_Wiki'
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('libao' 'ffmpeg' 'libmodplug' 'audiofile' 'libshout' 'libmad' 'curl' 'faad2'
'sqlite' 'jack' 'libmms' 'wavpack' 'avahi' 'libid3tag' 'yajl')
makedepends=('doxygen')
source=("http://downloads.sourceforge.net/musicpd/${pkgname}-${pkgver}.tar.bz2"
'ffmpeg.patch'
'tmpfiles.d'
'rc.d')
sha1sums=('f684d73a7517371a4461afdb2439f9533b51a49d'
'8a06d04bfdf4e0dc43479907dc9b3bd7fba6dd10'
'f4d5922abb69abb739542d8e93f4dfd748acdad7'
'3470d489565f0ed479f1665dd2876f66acb5a585')
backup=('etc/mpd.conf')
install=install
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i ../ffmpeg.patch
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--enable-jack \
--enable-lastfm \
--enable-soundcloud \
--enable-pulse \
--disable-sidplay \
--with-systemdsystemunitdir=/usr/lib/systemd/system
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
sed \
-e '/^#playlist_directory/c playlist_directory "/var/lib/mpd/playlists"' \
-e '/^#db_file/c db_file "/var/lib/mpd/mpd.db"' \
-e '/^#pid_file/c pid_file "/run/mpd/mpd.pid"' \
-e '/^#state_file/c state_file "/var/lib/mpd/mpdstate"' \
-e '/^#user/c user "mpd"' \
-i doc/mpdconf.example
install -Dm755 ../rc.d "${pkgdir}"/etc/rc.d/mpd
install -d -g 45 -o 45 "${pkgdir}"/var/lib/mpd/playlists
install -Dm644 doc/mpdconf.example "${pkgdir}"/etc/mpd.conf
install -Dm644 ../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/mpd.conf
}
|
