blob: d798a12e17dab5e6eecefe1443e8e2511a755349 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 164647 2012-08-01 18:37:45Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Geoffroy Carrier <geoffroy@archlinux.org>
pkgbase=obexd
pkgname=('obexd-client' 'obexd-server')
pkgver=0.47
pkgrel=1
url="http://www.bluez.org/"
arch=('i686' 'x86_64')
license=('GPL2')
makedepends=('bluez' 'libical')
source=("http://www.kernel.org/pub/linux/bluetooth/${pkgbase}-${pkgver}.tar.bz2")
md5sums=('af721152055c40a226e374c2dd989901')
build() {
cd "${srcdir}/${pkgbase}-${pkgver}"
./configure --prefix=/usr \
--libexecdir=/usr/lib/obexd
make
}
package_obexd-client() {
pkgdesc="D-Bus service providing high-level OBEX client side functionality"
depends=('bluez')
provides=("obexd=${pkgver}")
replaces=('obexd')
conflicts=('obexd')
cd "${srcdir}/${pkgbase}-${pkgver}/client"
install -m755 -d "${pkgdir}/usr/lib/obexd"
install -m755 -d "${pkgdir}/usr/share/dbus-1/services"
install -m755 obex-client "${pkgdir}/usr/lib/obexd/"
install -m644 obex-client.service "${pkgdir}/usr/share/dbus-1/services/"
}
package_obexd-server() {
pkgdesc="D-Bus service providing high-level OBEX server side functionality"
depends=('bluez' 'libical')
conflicts=('obex-data-server')
cd "${srcdir}/${pkgbase}-${pkgver}/src"
install -m755 -d "${pkgdir}/usr/lib/obexd"
install -m755 -d "${pkgdir}/usr/share/dbus-1/services"
install -m755 obexd "${pkgdir}/usr/lib/obexd/"
install -m644 obexd.service "${pkgdir}/usr/share/dbus-1/services/"
}
|
