blob: adb4124d149dcb543a7f6e383dd2d9c453d6df72 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 153724 2012-03-18 19:07:27Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor : shining <shiningxc.at.gmail.com>
# Contributor : cyberdune <cyberdune@gmail.com>
pkgname=octave
pkgver=3.6.1
pkgrel=2
pkgdesc="A high-level language, primarily intended for numerical computations."
arch=('i686' 'x86_64')
url="http://www.octave.org"
license=('GPL')
depends=('fftw' 'pcre' 'curl' 'lapack' 'libx11' 'graphicsmagick' 'glpk' 'hdf5' 'gcc-libs' 'qhull' 'fltk' 'suitesparse')
makedepends=('texinfo' 'graphicsmagick' 'gcc-fortran' 'suitesparse' 'texlive-core')
optdepends=('texinfo: for help-support in octave'
'gnuplot: alternative plotting')
source=("ftp://ftp.gnu.org/gnu/octave/octave-$pkgver.tar.bz2")
options=('!emptydirs')
install=octave.install
sha1sums=('46fdc0b3d7db1b0266975a7443e26769c939a9c7')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
# http://www.nabble.com/Random-rounding-errors-td16010966.html
FFLAGS="-O -ffloat-store" \
./configure --prefix=/usr --libexecdir=/usr/lib \
--enable-shared --disable-static
LANG=C make
}
package(){
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
# add octave library path to ld.so.conf.d
install -d ${pkgdir}/etc/ld.so.conf.d
echo "/usr/lib/${pkgname}-${pkgver}" > ${pkgdir}/etc/ld.so.conf.d/${pkgname}.conf
}
|
