blob: 3699ffa681a1b70af4e318941500d53c2ee6c642 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# $Id: PKGBUILD 141215 2011-10-26 14:54:11Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=pangomm
pkgname=('pangomm' 'pangomm-docs')
pkgver=2.28.4
pkgrel=1
arch=('i686' 'x86_64')
license=('LGPL')
makedepends=('pango' 'glibmm' 'glibmm-docs' 'cairomm' 'pkgconfig')
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/2.28/${pkgname}-${pkgver}.tar.xz)
options=('!libtool')
url="http://gtkmm.sourceforge.net/"
sha256sums=('778dcb66a793cbfd52a9f92ee5a71b888c3603a913fc1ddc48a30204de6d6c82')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr
make
}
package_pangomm() {
pkgdesc="C++ bindings for pango"
depends=('pango' 'glibmm' 'cairomm')
cd "${srcdir}/${pkgbase}-${pkgver}"
sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
make DESTDIR="${pkgdir}" install
}
package_pangomm-docs() {
pkgdesc="Developer documentation for pangomm"
cd "${srcdir}/${pkgbase}-${pkgver}/docs"
make DESTDIR="${pkgdir}" install
}
|
