summaryrefslogtreecommitdiff
path: root/extra/perl-yaml-syck/PKGBUILD
blob: e1f29bada8bbdba419d88ce0326183e4d15578c3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# $Id: PKGBUILD 153683 2012-03-17 20:26:21Z eric $
# This PKGBUILD was generated by cpan4pacman via CPANPLUS::Dist::Pacman
# Maintainer: kevin <kevin@archlinux.org>

pkgname=perl-yaml-syck
_realname=YAML-Syck
pkgver=1.20
pkgrel=1
pkgdesc="Fast, lightweight YAML loader and dumper"
arch=('i686' 'x86_64')
license=('custom')
url="http://search.cpan.org/dist/${_realname}/"
depends=('perl>=5.10.0')
options=('!emptydirs')
source=(http://www.cpan.org/authors/id/T/TO/TODDR/${_realname}-$pkgver.tar.gz)
md5sums=('8f6d04ee5817b8479e1234264a8d458d')

build() {
  cd "${srcdir}/${_realname}-$pkgver"

  # install module in vendor directories.
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/${_realname}-$pkgver"
  make test
}

package() {
  cd "${srcdir}/${_realname}-$pkgver"
  make install DESTDIR="${pkgdir}"

  # remove perllocal.pod and .packlist
  find "${pkgdir}" -name perllocal.pod -delete
  find "${pkgdir}" -name .packlist -delete

  # license.
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}