blob: 7222d82f8f8580486ab1dfae2243dacc80ef0d2a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# $Id: PKGBUILD 120090 2011-04-19 21:33:57Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=pygobject
pkgname=(pygobject py3gobject pygobject-devel)
pkgver=2.28.4
pkgrel=1
arch=('i686' 'x86_64')
license=('LGPL')
depends=('glib2' 'gobject-introspection')
makedepends=(python python2 python-cairo python2-cairo)
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgbase}/${pkgver%.*}/${pkgbase}-${pkgver}.tar.bz2)
options=('!libtool')
url="http://www.pygtk.org/"
sha256sums=('70e3a05dd5f688e68b5dafa2412cd4fdbc0af83792a5752ef6353c4accf2022c')
build() {
cd "${srcdir}"
cp -a "${pkgbase}-${pkgver}" python2-build
mkdir devel
(
cd python2-build
export PYTHON=/usr/bin/python2
./configure --prefix=/usr
make
)
(
cd "${pkgbase}-${pkgver}"
./configure --prefix=/usr
make
)
}
package_pygobject() {
pkgdesc="Python 2 bindings for GObject"
depends+=('python2' 'python2-cairo' 'pygobject-devel')
cd "${srcdir}/python2-build"
make DESTDIR="${pkgdir}" install
find "$pkgdir"/usr/share/pygobject -name '*.py' | \
xargs sed -i "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|"
# Split devel stuff
mv "$pkgdir"/usr/{bin,include,lib/pkgconfig,share/{gtk-doc,pygobject/{2.0/codegen,xsl}}} \
"$srcdir/devel/"
}
package_py3gobject() {
pkgdesc="Python 3 bindings for GObject"
depends+=('python' 'python-cairo' 'pygobject-devel')
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
# Delete devel stuff
rm -r "$pkgdir"/usr/{bin,include,lib/pkgconfig,share/{gtk-doc,pygobject/{2.0/codegen,xsl}}}
}
package_pygobject-devel() {
pkgdesc="Development files for the pygobject bindings"
depends=(python2)
cd "${srcdir}/devel"
mkdir -p "$pkgdir"/usr/{include,lib,share/pygobject/2.0}
mv bin "$pkgdir/usr/"
mv include "$pkgdir/usr/"
mv pkgconfig "$pkgdir/usr/lib/"
mv gtk-doc "$pkgdir/usr/share/"
mv codegen "$pkgdir/usr/share/pygobject/2.0/"
mv xsl "$pkgdir/usr/share/pygobject/"
}
|
