blob: 43c056c6b145be8cb72b3390acc33bd65074c3be (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
|
# $Id: PKGBUILD 179054 2013-03-02 09:03:00Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
pkgname=qt4
pkgver=4.8.4
pkgrel=13
arch=('i686' 'x86_64' 'mips64el')
url='http://qt-project.org/'
license=('GPL3' 'LGPL')
pkgdesc='A cross-platform application and UI framework'
depends=('libtiff' 'libpng' 'libmng' 'sqlite' 'ca-certificates' 'dbus'
'fontconfig' 'libgl' 'libxrandr' 'libxv' 'libxi' 'alsa-lib'
'xdg-utils' 'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('postgresql-libs' 'mysql' 'unixodbc' 'cups' 'gtk2'
'mesa-libgl')
optdepends=('postgresql-libs: PostgreSQL driver'
'libmysqlclient: MySQL driver'
'unixodbc: ODBC driver'
'libxinerama: Xinerama support'
'libxcursor: Xcursor support'
'libxfixes: Xfixes support'
'icu: Unicode support')
if [ "$CARCH" != "mips64el" ]; then
makedepends+=('libfbclient')
optdepends+=('libfbclient: Firebird/iBase driver')
fi
install="${pkgname}.install"
options=('!libtool')
replaces=('qt<=4.8.4')
conflicts=('qt')
_pkgfqn="qt-everywhere-opensource-src-${pkgver}"
source=("http://releases.qt-project.org/${pkgname}/source/${_pkgfqn}.tar.gz"
'qtconfig.desktop' 'qt4.profile'
'improve-cups-support.patch'
'declarative-fix-sigbus.patch')
md5sums=('89c5ecba180cae74c66260ac732dc5cb'
'20ca06ef59775d749b9451ce7437fa9a'
'4ed0bd79a310e2b5d34fc71760b99139'
'c439c7731c25387352d8453ca7574971'
'aac963d05a9d5733e2bfce9e26607f51')
build() {
cd ${_pkgfqn}
# (FS#28381) (KDEBUG#180051)
patch -p1 -i "${srcdir}"/improve-cups-support.patch
# MIPS N32-specific fix, shouldn't affect correctness on other platforms.
patch -Np1 -i "${srcdir}/declarative-fix-sigbus.patch"
export QT4DIR="${srcdir}"/${_pkgfqn}
export LD_LIBRARY_PATH=${QT4DIR}/lib:${LD_LIBRARY_PATH}
[ "${CARCH}" = "mips64el" ] && export CXXFLAGS="${CXXFLAGS} -fpermissive"
sed -i "s|-O2|${CXXFLAGS}|" mkspecs/common/{g++,gcc}-base.conf
sed -i "/^QMAKE_LFLAGS_RPATH/s| -Wl,-rpath,||g" mkspecs/common/gcc-base-unix.conf
sed -i "/^QMAKE_LFLAGS\s/s|+=|+= ${LDFLAGS}|g" mkspecs/common/gcc-base.conf
[ "$CARCH" != "mips64el" ] && extra="-plugin-sql-ibase"
./configure -confirm-license -opensource \
-prefix /usr \
-bindir /usr/lib/qt4/bin \
-headerdir /usr/include/qt4 \
-docdir /usr/share/doc/qt4 \
-plugindir /usr/lib/qt4/plugins \
-importdir /usr/lib/qt4/imports \
-datadir /usr/share/qt4 \
-translationdir /usr/share/qt4/translations \
-sysconfdir /etc/xdg \
-examplesdir /usr/share/doc/qt4/examples \
-demosdir /usr/share/doc/qt4/demos \
-plugin-sql-{psql,mysql,sqlite,odbc} \
-system-sqlite \
-no-phonon \
-no-phonon-backend \
-no-webkit \
-graphicssystem raster \
-openssl-linked \
-nomake demos \
-nomake examples \
-nomake docs \
-silent \
-no-rpath \
-optimized-qmake \
-reduce-relocations \
-dbus-linked \
-no-openvg \
$extra
make
}
package() {
cd ${_pkgfqn}
make INSTALL_ROOT="${pkgdir}" install
# install missing icons and desktop files
install -D -m644 src/gui/dialogs/images/qtlogo-64.png \
"${pkgdir}/usr/share/icons/hicolor/64x64/apps/qt4logo.png"
install -Dm644 "${srcdir}"/qtconfig.desktop \
"${pkgdir}/usr/share/applications/qtconfig4.desktop"
# install the profile
install -D -m755 "${srcdir}"/qt4.profile "${pkgdir}"/etc/profile.d/qt4.sh
# Useful symlinks for cmake and configure scripts
install -d "${pkgdir}"/usr/bin
for b in "${pkgdir}"/usr/lib/qt4/bin/*; do
ln -s /usr/lib/qt4/bin/$(basename $b) "${pkgdir}"/usr/bin/$(basename $b)-qt4
done
# install license addition
install -D -m644 LGPL_EXCEPTION.txt \
${pkgdir}/usr/share/licenses/${pkgname}/LGPL_EXCEPTION.txt
# Fix wrong libs path in pkgconfig files
find "${pkgdir}/usr/lib/pkgconfig" -type f -name '*.pc' \
-exec perl -pi -e "s, -L${srcdir}/?\S+,,g" {} \;
# Fix wrong bins path in pkgconfig files
find "${pkgdir}/usr/lib/pkgconfig" -type f -name '*.pc' \
-exec sed -i 's|/usr/bin/|/usr/lib/qt4/bin/|g' {} \;
# Fix wrong path in prl files
find "${pkgdir}/usr/lib" -type f -name '*.prl' \
-exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d;s/\(QMAKE_PRL_LIBS =\).*/\1/' {} \;
# The TGA plugin is broken (FS#33568)
rm "${pkgdir}"/usr/lib/qt4/plugins/imageformats/libqtga.so
}
|
