blob: e11458b3c00c3d43e581accfe8e650d67dfde429 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# $Id: PKGBUILD 111269 2011-02-25 16:10:57Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>
# Contributor: K. Piche <kpiche@rogers.com>
pkgname=r
pkgver=2.12.2
pkgrel=1
pkgdesc="R is a language and environment for statistical computing and graphics"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url=('http://www.r-project.org/')
depends=('blas' 'lapack' 'bzip2' 'libpng' 'libjpeg' 'libtiff'
'ncurses' 'pcre' 'readline' 'zlib' 'perl' 'gcc-libs'
'tk' 'libxt' 'libxmu' 'pango')
makedepends=('openjdk6' 'gcc-fortran')
options=('!makeflags')
source=("http://cran.r-project.org/src/base/R-2/R-${pkgver}.tar.gz"
'r.desktop'
'r.png')
sha1sums=('dbdc46edbab2dbbdc115b7247f80da5fee3dd912'
'bcc0320d7cc49d56408edc756b50a0f9ba98fe43'
'a69a07ec363440efc18ce0a7f2af103375dea978')
build() {
cd ${srcdir}/R-${pkgver}
sed -i 's|#define NeedFunctionPrototypes 0|#define NeedFunctionPrototypes 1|g' src/modules/X11/dataentry.c
./configure --prefix=/usr \
--libdir=/usr/lib \
--datarootdir=/usr/share \
rsharedir=/usr/share/R/ \
rincludedir=/usr/include/R/ \
rdocdir=/usr/share/R/docs/ \
--with-gnu-ld \
--with-readline \
--with-x \
--with-zlib \
--with-bzlib \
--with-pcre \
--enable-R-shlib \
--with-lapack \
--with-blas \
F77=gfortran \
LIBnn=lib
make
}
package() {
cd ${srcdir}/R-${pkgver}
make -j1 DESTDIR=${pkgdir} install
# Fixup R wrapper scripts.
sed -i "s|${pkgdir} ||" ${pkgdir}/usr/bin/R
rm ${pkgdir}/usr/lib/R/bin/R
cd ${pkgdir}/usr/lib/R/bin
ln -s ../../../bin/R
# install some freedesktop.org compatibility
install -Dm644 ${srcdir}/r.desktop \
${pkgdir}/usr/share/applications/r.desktop
install -Dm644 ${srcdir}/r.png \
${pkgdir}/usr/share/pixmaps/r.png
}
|
