blob: b34a91398986978017784e0bb93488bc520c70eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 150948 2012-02-24 09:50:09Z pierre $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: juergen <juergen@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
pkgname=ratpoison
pkgver=1.4.5
pkgrel=5
pkgdesc="A simple keystroke-driven window manager"
arch=('i686' 'x86_64')
license=('GPL')
depends=('libxinerama' 'readline' 'bash' 'perl' 'libxtst' 'libxft' 'texinfo')
url="http://www.nongnu.org/ratpoison/"
install="${pkgname}.install"
source=("http://savannah.nongnu.org/download/${pkgname}/${pkgname}-${pkgver}.tar.gz"
"${pkgname}.desktop")
md5sums=('330a08dbed6be88cab54f6947e9f0b60'
'29c3cb9be59758e39d8471391231a74a')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr
make CFLAGS="$CFLAGS -DHAVE_GETLINE"
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# fix permissions
chmod a+x ${pkgdir}/usr/share/ratpoison/{allwindows.sh,clickframe.pl,rpshowall.sh,rpws,split.sh}
# Not useful outside the source tree. Kill it
rm ${pkgdir}/usr/share/ratpoison/genrpbindings
cd contrib
./genrpbindings
install -dm755 ${pkgdir}/usr/share/ratpoison/bindings
install -m644 {Ratpoison.pm,ratpoison-cmd.el,ratpoison.rb,ratpoison.lisp,ratpoison.py} \
${pkgdir}/usr/share/ratpoison/bindings/
install -Dm644 ${srcdir}/${pkgname}.desktop \
${pkgdir}/etc/X11/sessions/${pkgname}.desktop
install -Dm644 ${pkgdir}/usr/share/ratpoison/ratpoison.el \
${pkgdir}/usr/share/emacs/site-lisp/ratpoison.el
}
|
