blob: e333c52c45d72b4620ed0f45ed7b7967d004fa08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 198399 2013-10-30 14:38:03Z allan $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
pkgname=rhythmbox
pkgver=3.0.1
pkgrel=1
pkgdesc="An iTunes-like music playback and management application"
arch=(i686 x86_64)
license=(GPL)
url="http://www.rhythmbox.org"
depends=(dconf desktop-file-utils gst-plugins-base gst-plugins-good libsoup json-glib libnotify libpeas media-player-info totem-plparser tdb webkitgtk3 python-gobject gnome-icon-theme)
makedepends=(itstool intltool brasero gobject-introspection vala grilo libdmapsharing lirc-utils libgpod libmtp)
optdepends=('gst-plugins-ugly: Extra media codecs'
'gst-plugins-bad: Extra media codecs'
'gst-libav: Extra media codecs'
'brasero: Audio CD Recorder plugin'
'libdmapsharing: DAAP Music Sharing plugin'
'grilo-plugins: Grilo media browser plugin'
'lirc-utils: LIRC plugin'
'libgpod: Portable Players - iPod plugin'
'libmtp: Portable Players - MTP plugin'
'zeitgeist: Zeitgeist plugin')
options=('!emptydirs')
install=rhythmbox.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver::3}/$pkgname-$pkgver.tar.xz)
sha256sums=('75072b093284e9f5696fbb590d719a9e16340a5a91d73e3ccd876ce21329bdcf')
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/rhythmbox \
--localstatedir=/var --disable-static \
--enable-daap --enable-python --enable-vala
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
rm -r "$pkgdir/usr/lib/rhythmbox/sample-plugins"
}
|
