blob: 066f751b0856a30c196bd40ca45f7a917044ec46 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 199804 2013-11-16 21:20:01Z schiv $
# Maintainer: Ray Rashif <schiv@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Robert Emil Berge <robert@rebi.no>
pkgname=rosegarden
pkgver=13.10
pkgrel=1
pkgdesc="MIDI/audio sequencer and notation editor"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.rosegardenmusic.com/"
license=('GPL')
depends=('liblrdf' 'dssi' 'fftw' 'lirc-utils'
'perl' 'qt4' 'shared-mime-info')
makedepends=('imake')
optdepends=('lilypond: notation display'
'cups: printing support'
'okular: print preview, or any other PDF viewer'
'timidity++: MIDI playback, or any other softsynth'
'flac'
'wavpack')
[ "$CARCH" = "i686" ] && optdepends+=('dssi-vst: win32 VST support')
install=$pkgname.install
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2")
md5sums=('730a830da4d3b60fa8b15716d8dcd8a4')
build() {
cd "$srcdir/$pkgname-$pkgver"
# lrdf + raptor2 compatibility
lrdf_CFLAGS="$(pkg-config --cflags raptor2)"
# qt4 compatibility (qt->qt5)
LRELEASE=/usr/lib/qt4/bin/lrelease
LUPDATE=/usr/lib/qt4/bin/lupdate
export lrdf_CFLAGS LRELEASE LUPDATE
./configure --prefix=/usr
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
