blob: b2d49d466d96a7220ae75054cf501ec332a3e6ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 150933 2012-02-24 01:09:55Z tdziedzic $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=rrdtool
pkgver=1.4.5
pkgrel=6
pkgdesc="Data logging and graphing application"
arch=('i686' 'x86_64')
url="http://www.rrdtool.org"
license=('GPL' 'custom')
depends=('libxml2' 'pango' 'ttf-dejavu')
makedepends=('intltool' 'ruby' 'python2' 'tcl' 'lua')
optdepends=('tcl: to use corresponding binding' \
'python2: to use corresponding binding' \
'ruby: to use corresponding binding' \
'lua: to use corresponding binding')
options=('!libtool' '!emptydirs' '!makeflags')
source=(http://oss.oetiker.ch/rrdtool/pub/rrdtool-${pkgver}.tar.gz)
sha1sums=('56638e8aedd5d5522152e86746e382b75dc48c35')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i 's|-lrrd|-lrrd -L/usr/lib/perl5/core_perl/CORE/ -lperl |' bindings/perl-shared/Makefile.PL
# fix FS#28521 make ruby install to vendor_ruby instead of site_ruby
sed -e 's/$(RUBY) extconf.rb/& --vendor/' -i bindings/Makefile.in
PYTHON=python2 ./configure --prefix=/usr --localstatedir=/var --disable-rpath \
--enable-perl --enable-perl-site-install --with-perl-options='INSTALLDIRS=vendor' \
--enable-ruby --enable-ruby-site-install --enable-python \
--enable-lua --enable-lua-site-install --enable-tcl --disable-libwrap
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -D -m644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
