blob: 2d2a89d307a6680b1e493ce914e99c3113436f4d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 145618 2011-12-24 05:53:53Z angvp $
# Maintainer: Angel Velasquez <angvp@archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
pkgname=rxvt-unicode
pkgver=9.14
pkgrel=1
pkgdesc="An unicode enabled rxvt-clone terminal emulator (urxvt)"
arch=('i686' 'x86_64')
url="http://software.schmorp.de/pkg/rxvt-unicode.html"
license=('GPL')
depends=('gcc-libs' 'libxft' 'gdk-pixbuf2' 'perl')
optdepends=('gtk2-perl: to use the urxvt-tabbed')
changelog=ChangeLog
source=(http://dist.schmorp.de/rxvt-unicode/${pkgname}-${pkgver}.tar.bz2 \
${pkgname}.desktop)
md5sums=('022235a9a8b012c29e72c49177be6ce4'
'3de6c13126a45bc3bc9f6bba077a1311')
sha1sums=('e303b7591225b06bc04e18a875461438c635014e'
'962aebc88982dbeb62a7c4a051ff567e015f61a0')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr \
--with-terminfo=/usr/share/terminfo \
--enable-256-color \
--enable-font-styles \
--enable-xim \
--enable-keepscrolling \
--enable-selectionscrolling \
--enable-smart-resize \
--enable-pixbuf \
--enable-transparency \
--enable-utmp \
--enable-wtmp \
--enable-lastlog \
--disable-frills
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
install -d "${pkgdir}/usr/share/terminfo"
export TERMINFO="${pkgdir}/usr/share/terminfo"
make DESTDIR="${pkgdir}" install
# install the tabbing wrapper ( requires gtk2-perl! )
sed -i 's/\"rxvt\"/"urxvt"/' doc/rxvt-tabbed
install -Dm 755 doc/rxvt-tabbed "${pkgdir}/usr/bin/urxvt-tabbed"
# install freedesktop menu
install -Dm644 ../${pkgname}.desktop \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
}
|
