blob: 9cf031abd60fc736aec29e4a3141a54f7378cd89 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 178994 2013-03-01 10:25:10Z andrea $
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: Ben <ben@benmazer.net>
# Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=scribus
pkgver=1.4.2
pkgrel=2
pkgdesc="A desktop publishing program"
arch=('i686' 'x86_64')
url="http://www.scribus.net"
license=('GPL')
install=scribus.install
depends=('libcups>=1.3.11' 'lcms2' 'qt4' 'ghostscript>=8.70' \
'libart-lgpl>=2.3.20' 'python2' 'libxml2>=2.7.3' 'cairo' \
'desktop-file-utils' 'shared-mime-info' \
'hyphen' 'aspell' 'boost-libs')
makedepends=('cmake' 'boost' 'mesa')
options=(!libtool)
source=(http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.xz)
sha1sums=('6e67e98fa315a2890d9cbb12eed49ecebb7f11cb')
build() {
cd "${srcdir}"
sed -i -e 's|#!/usr/bin/python|#!/usr/bin/python2|' \
-e 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
scribus-${pkgver}/scribus/plugins/scriptplugin/{samples,scripts}/*
mkdir build
cd build
cmake ../scribus-${pkgver} \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON \
-DWANT_CAIRO=1 \
-DLIB_SUFFIX=""
make
}
package() {
cd "${srcdir}/build"
make DESTDIR="${pkgdir}" install
# fix icon path in .desktop file
sed -i 's|Icon=scribus|Icon=/usr/share/scribus/icons/scribus.png|' \
"${srcdir}/scribus-${pkgver}/scribus.desktop"
install -Dm644 "${srcdir}/scribus-${pkgver}/scribus.desktop" \
"${pkgdir}/usr/share/applications/scribus.desktop"
}
|
