blob: 76aa6c8c0a5fd2feec994534ede417456a356e63 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
pkgname=sdl2
pkgver=2.0.1
pkgrel=2
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2)"
arch=('i686' 'x86_64')
url="http://www.libsdl.org"
license=('MIT')
depends=('glibc' 'libxext' 'libxrender' 'libx11' 'libgl')
makedepends=('alsa-lib' 'mesa' 'libpulse' 'libxrandr' 'libxinerama')
optdepends=('alsa-lib: ALSA audio driver'
'libpulse: PulseAudio audio driver')
source=("http://www.libsdl.org/release/SDL2-${pkgver}.tar.gz")
md5sums=('0eb97039488bf463e775295f7b18b227')
prepare() {
mkdir build
}
build() {
cd build
../SDL2-$pkgver/configure --prefix=/usr \
--enable-sdl-dlopen \
--disable-arts --disable-esd --disable-nas \
--enable-alsa --enable-pulseaudio-shared \
--disable-rpath
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
install -Dm644 ../SDL2-$pkgver/COPYING.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|