blob: bcc7c74318d6edc3a76f690d5c394197707fe03d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 185473 2013-05-14 11:01:28Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Michel Brabants <michel.linux@tiscali.be>
pkgname=seahorse
pkgver=3.8.2
pkgrel=1
pkgdesc="GNOME application for managing PGP keys."
arch=(i686 x86_64 'mips64el')
license=(GPL)
url="http://projects.gnome.org/seahorse/"
depends=(gtk3 gcr libsecret libsoup gpgme desktop-file-utils hicolor-icon-theme dconf)
makedepends=(libldap intltool yelp-tools gobject-introspection openssh libsm)
optdepends=('openssh: SSH support')
provides=(x11-ssh-askpass)
options=('!libtool' '!emptydirs')
groups=(gnome-extra)
install=seahorse.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver::3}/$pkgname-$pkgver.tar.xz
seahorse-ssh-askpass.sh)
sha256sums=('b3837d088b7e3f7ebc41cb3f11c5c85e2df7e06bdc538a3e85bb1a13c34c9a12'
'400ea9a6084acc93f1dbd4223b95622bbd48071b763063328efba00de378b68c')
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--enable-ldap --enable-hkp \
--disable-schemas-compile
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm755 "$srcdir/seahorse-ssh-askpass.sh" \
"$pkgdir/etc/profile.d/seahorse-ssh-askpass.sh"
}
|
