blob: 79e2e11effb36d57a3ae775ee9e8fe20551fa989 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 183457 2013-04-21 22:12:07Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Michel Brabants <michel.linux@tiscali.be>
pkgname=seahorse
pkgver=3.8.1
pkgrel=1
pkgdesc="GNOME application for managing PGP keys."
arch=(i686 x86_64 'mips64el')
license=(GPL)
url="http://projects.gnome.org/seahorse/"
depends=(gtk3 gcr libsecret libsoup gpgme desktop-file-utils hicolor-icon-theme dconf)
makedepends=(libldap intltool yelp-tools gobject-introspection openssh libsm)
optdepends=('openssh: SSH support')
provides=(x11-ssh-askpass)
options=('!libtool' '!emptydirs')
groups=(gnome-extra)
install=seahorse.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver::3}/$pkgname-$pkgver.tar.xz
seahorse-ssh-askpass.sh)
sha256sums=('c1a1d97618a37a79e19902e00f3a0de7cfb947b52eb9282ea09e5f9f73151e7a'
'400ea9a6084acc93f1dbd4223b95622bbd48071b763063328efba00de378b68c')
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--enable-ldap --enable-hkp \
--disable-schemas-compile
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm755 "$srcdir/seahorse-ssh-askpass.sh" \
"$pkgdir/etc/profile.d/seahorse-ssh-askpass.sh"
}
|
