blob: f997734ef0c912eecdbcde4fb3b8b0682bb0780c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id: PKGBUILD 163539 2012-07-15 05:04:36Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Jeff Mickey <jeff@archlinux.org>
# Contributor: Jani Talikka <jani.talikka@gmail.com>
# Contributor: Ralf Barth <archlinux.org@haggy.org>
pkgname=smartmontools
pkgver=5.43
pkgrel=1
pkgdesc="Control and monitor S.M.A.R.T. enabled ATA and SCSI Hard Drives"
url="http://smartmontools.sourceforge.net"
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
depends=('gcc-libs' 'libcap-ng' 'bash')
backup=('etc/smartd.conf'
'etc/conf.d/smartd')
source=("http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz"
'smartd.conf'
'smartd.rc')
md5sums=('a1cb2c3d8cc2de377037fe9e7cef40a9'
'28c1b80c41dac52d433961dcfb4f70e0'
'fb30e07f87f2c1d99532e018291ad3e8')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--enable-drivedb \
--with-libcap-ng=yes \
--with-systemdsystemunitdir=/usr/lib/systemd/system
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i -e "s:sysconfig/smartmontools:conf.d/smartd:g" smartd.service
sed -i -e "s:smartd_opts:SMARTD_ARGS:g" smartd.service
make DESTDIR="${pkgdir}" install
rm -rf ${pkgdir}/etc/rc.d
install -Dm755 ${srcdir}/smartd.rc "${pkgdir}/etc/rc.d/smartd"
install -Dm644 ${srcdir}/smartd.conf "${pkgdir}/etc/conf.d/smartd"
}
|
