blob: 772e17688fd019d57289398accfe0f8b9e510d49 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 166939 2012-09-22 20:17:43Z dreisner $
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Antony Male <antony dot male at geemail dot com>>
pkgname=snappy
pkgver=1.0.5
pkgrel=2
pkgdesc='A fast compressor/decompressor library'
arch=('i686' 'x86_64' 'mips64el')
url="http://code.google.com/p/snappy/"
license=('BSD')
depends=('glibc' 'gcc-libs')
checkdepends=('zlib')
options=('!libtool')
source=("http://snappy.googlecode.com/files/$pkgname-$pkgver.tar.gz")
md5sums=('4c0af044e654f5983f4acbf00d1ac236')
build() {
cd "$pkgname-$pkgver"
# compile without assertions
CXXFLAGS+=\ -DNDEBUG
./configure --prefix=/usr
make
}
check() {
# compile without assertions
CXXFLAGS+=\ -DNDEBUG
make -C "$pkgname-$pkgver" check
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -m644 -D COPYING "$pkgdir/usr/share/licenses/snappy/LICENSE"
}
# vim:set ts=2 sw=2 et:
|
