blob: 0868a848a4f7f8135644ccd6cdd8243b26569456 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 184435 2013-05-06 19:39:45Z foutrelis $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=sox
pkgver=14.4.1
pkgrel=2
pkgdesc="The Swiss Army knife of sound processing tools"
arch=('i686' 'x86_64')
url="http://sox.sourceforge.net/"
license=('GPL' 'LGPL')
depends=('libltdl' 'file' 'libsndfile' 'libpng' 'lame' 'opencore-amr' 'gsm')
makedepends=('ffmpeg' 'libao' 'libmad' 'libid3tag' 'wavpack' 'libpulse')
checkdepends=('time')
optdepends=('libao: for ao plugin'
'ffmpeg: for ffmpeg plugin'
'libmad: for mp3 plugin'
'libid3tag: for mp3 plugin'
'wavpack: for wavpack plugin'
'libpulse: for pulse plugin')
options=('!libtool')
source=(http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2
sox-ffmpeg0.11.patch)
sha1sums=('4775f9e9eebb5a2fe79df548908a7a24088118d9'
'2f92bcaebcaf300782396f106cdd27c72048a851')
prepare() {
cd ${pkgname}-${pkgver}
patch -p1 -i "${srcdir}/sox-ffmpeg0.11.patch"
sed -i 's|man1/sox.1 soxeffect.7|man1/sox.1.gz soxeffect.7.gz|' Makefile.in
}
build() {
cd ${pkgname}-${pkgver}
./configure --prefix=/usr --sysconfdir=/etc \
--with-dyn-default --with-distro="Arch Linux"
make
}
check() {
cd ${pkgname}-${pkgver}
make bindir=. installcheck
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
}
|
