blob: d5699b83e1dcb7df797353fb856450c22f7d17ec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# $Id: PKGBUILD 187368 2013-06-05 15:55:32Z bluewind $
# Maintainer: Florian Pritz <bluewind@xinu.at>
# Contributor: Dale Blount <dale@archlinux.org>
# Contributor: Manolis Tzanidakis
pkgname=spamassassin
pkgver=3.3.2
pkgrel=9
pkgdesc="A mail filter to identify spam."
arch=('i686' 'x86_64')
license=('APACHE')
url="http://spamassassin.apache.org"
depends=('openssl' 'zlib' 're2c' 'perl-net-dns' 'perl-io-socket-ssl'
'perl-libwww' 'perl-mail-spf' 'perl-http-message' 'perl-net-http'
'perl-io-socket-inet6' 'perl-mail-dkim' 'perl-crypt-ssleay')
makedepends=('razor' 'perl-dbi')
optdepends=('razor: to identify collaborately-flagged spam')
backup=('etc/mail/spamassassin/local.cf'
'etc/mail/spamassassin/init.pre'
'etc/mail/spamassassin/v310.pre'
'etc/mail/spamassassin/v312.pre'
'etc/mail/spamassassin/v320.pre'
'etc/mail/spamassassin/v330.pre')
install="${pkgname}.install"
options=('!emptydirs')
source=("http://mirrors.devlib.org/apache/${pkgname}/source/Mail-SpamAssassin-${pkgver}.tar.gz"
'spamassassin.service'
'perl-5.18-fixes.patch')
md5sums=('d1d62cc5c6eac57e88c4006d9633b81e'
'b8dcea016fb73b074b941e832cfae5c9'
'6cf63928eeeaea25967c2ffd875d106a')
prepare() {
cd "${srcdir}/Mail-SpamAssassin-${pkgver}"
patch -p0 -d lib -i "$srcdir/perl-5.18-fixes.patch"
}
build() {
cd "${srcdir}/Mail-SpamAssassin-${pkgver}"
# install module in vendor directories.
PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor \
CONTACT_ADDRESS=root@localhost ENABLE_SSL=yes PERL_TAINT=no
make
}
check() {
cd "${srcdir}/Mail-SpamAssassin-${pkgver}"
# SSLv2 is disabled by upstream so this test would fail
rm -rf t/spamd_ssl_v2.t
# parallel tests cause lots of failures; disable for now
#export HARNESS_OPTIONS="j$(echo $MAKEFLAGS | sed 's/.*-j\([0-9][0-9]*\).*/\1/')"
make test
}
package() {
cd "${srcdir}/Mail-SpamAssassin-${pkgver}"
make DESTDIR="${pkgdir}" install
install -D -m644 "${srcdir}/spamassassin.service" "${pkgdir}/usr/lib/systemd/system/spamassassin.service"
}
|
