extra/telepathy-kde-accounts-kcm/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# $Id: PKGBUILD 183062 2013-04-17 06:09:00Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Laurent Carlier <lordheavym@gmail.com>

pkgname=telepathy-kde-accounts-kcm
_pkgname=ktp-accounts-kcm
pkgver=0.6.1
pkgrel=1
pkgdesc="KCM Module for configuring Telepathy Instant Messaging Accounts"
arch=('i686' 'x86_64' 'mips64el')
url="http://community.kde.org/Real-Time_Communication_and_Collaboration"
license=('GPL')
depends=('telepathy-kde-common-internals' 'telepathy-kde-contact-list')
makedepends=('cmake' 'automoc4' 'boost')
optdepends=('telepathy-gabble: XMPP/Jabber/GTalk support'
            'telepathy-haze: all protocols supported by libpurple')
groups=('kde-telepathy')
conflicts=('telepathy-kde-accounts-kcm-plugins')
replaces=('telepathy-kde-accounts-kcm-plugins')
source=("http://download.kde.org/stable/kde-telepathy/${pkgver}/src/${_pkgname}-${pkgver}.tar.bz2")
sha1sums=('a6ba149da9a52423a41fe99704e57344d384b1cc')

build() {
  mkdir build
  cd build
  cmake ../${_pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}