extra/telepathy-kde-auth-handler/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# $Id: PKGBUILD 197623 2013-10-27 14:21:06Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgname=telepathy-kde-auth-handler
_pkgname=ktp-auth-handler
pkgver=0.7.0
pkgrel=1
pkgdesc="Provide UI/KWallet Integration For Passwords and SSL Errors on Account Connect"
arch=('i686' 'x86_64' 'mips64el')
url="http://community.kde.org/Real-Time_Communication_and_Collaboration"
license=('GPL')
depends=('telepathy-kde-common-internals' 'qjson' 'qca-ossl' 'libaccounts-qt' 'signon')
makedepends=('cmake' 'automoc4')
groups=('kde-telepathy')
source=("http://download.kde.org/stable/kde-telepathy/${pkgver}/${_pkgname}-${pkgver}.tar.bz2")
sha1sums=('0abeef4bc6905f0b975505f9a215bfbafa4b02a3')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../${_pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}