blob: 29f155d28e67d1791fa81fabe7868e0d248e367a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 183462 2013-04-21 22:12:14Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=tomboy
pkgver=1.14.0
pkgrel=1
pkgdesc="Desktop note-taking application for Linux and Unix"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.gnome.org/projects/tomboy/"
depends=('gtk2' 'gtkspell' 'gconf' 'gconf-sharp' 'dbus-sharp' 'dbus-sharp-glib' 'mono-addins' 'hicolor-icon-theme')
makedepends=('intltool' 'pkgconfig' 'gnome-doc-utils')
options=('!libtool' '!emptydirs' '!makeflags')
install=tomboy.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('14c1e7f2c7d67d8603a7de95830c3b159779909e8a74c5a6ca9e08a2508fea18')
build() {
export MONO_SHARED_DIR="$srcdir/.wabi"
mkdir -p "$MONO_SHARED_DIR"
cd "$pkgname-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var \
--disable-update-mimedb
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 install
install -m755 -d "$pkgdir/usr/share/gconf/schemas"
gconf-merge-schema "$pkgdir/usr/share/gconf/schemas/$pkgname.schemas" --domain tomboy "$pkgdir"/etc/gconf/schemas/*.schemas
rm -f "$pkgdir"/etc/gconf/schemas/*.schemas
}
|
