1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# $Id: PKGBUILD 184438 2013-05-06 19:39:53Z foutrelis $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Alexander Fehr <pizzapunk gmail com>
pkgbase=tracker
pkgname=(tracker libtracker-sparql)
pkgver=0.16.1
_tver=${pkgver%.*}
pkgrel=1
pkgdesc="All-in-one indexer, search tool and metadata database"
arch=(i686 x86_64)
license=(GPL)
makedepends=(libgee libsecret upower libexif exempi
poppler-glib libgsf icu enca networkmanager gtk3
desktop-file-utils hicolor-icon-theme gobject-introspection
intltool giflib gst-plugins-base-libs totem-plparser
taglib libvorbis flac vala libgxps libnautilus-extension)
url="http://www.gnome.org"
options=('!libtool' '!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgbase/$_tver/$pkgbase-$pkgver.tar.xz)
sha256sums=('fbb94144826b00da0b427dc6f37d2679bd8dfec1dc992e857a47a0b453f0b771')
build() {
cd $pkgbase-$pkgver
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/tracker \
--disable-unit-tests \
--enable-libflac \
--enable-libvorbis
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package_tracker() {
depends=("libtracker-sparql=$pkgver-$pkgrel" libgee libsecret
upower libexif exempi poppler-glib libgsf enca
networkmanager gtk3 desktop-file-utils hicolor-icon-theme)
optdepends=('giflib: extractor for GIF data'
'gst-plugins-base-libs: video extractor'
'totem-plparser: playlist support'
'libvorbis: Vorbis metadata extractor'
'flac: FLAC metadata extractor'
'taglib: writeback for audio files'
"nautilus: edit files' tracker tags"
'libgxps: XPS extractor')
groups=('gnome')
install=tracker.install
cd $pkgbase-$pkgver
make DESTDIR="$pkgdir" install
### Split libtracker-sparql
mkdir -p "$srcdir"/sparql/usr/{include,lib}/tracker-$_tver
mkdir -p "$srcdir"/sparql/usr/lib/{girepository-1.0,pkgconfig}
mkdir -p "$srcdir"/sparql/usr/share/{gir-1.0,vala/vapi}
mv "$pkgdir"/usr/lib/libtracker-sparql-* "$srcdir/sparql/usr/lib"
mv "$pkgdir"/usr/lib/tracker-$_tver/*.so* \
"$srcdir/sparql/usr/lib/tracker-$_tver"
mv "$pkgdir"/usr/share/vala/vapi/tracker-sparql-* \
"$srcdir/sparql/usr/share/vala/vapi"
mv {"$pkgdir","$srcdir/sparql"}/usr/include/tracker-$_tver/libtracker-sparql
mv {"$pkgdir","$srcdir/sparql"}/usr/lib/girepository-1.0/Tracker-$_tver.typelib
mv {"$pkgdir","$srcdir/sparql"}/usr/lib/pkgconfig/tracker-sparql-$_tver.pc
mv {"$pkgdir","$srcdir/sparql"}/usr/share/gir-1.0/Tracker-$_tver.gir
}
package_libtracker-sparql() {
pkgdesc="$pkgdesc (SPARQL library)"
depends=(sqlite icu glib2 libffi pcre util-linux)
mv "$srcdir"/sparql/* "$pkgdir"
}
|
