blob: 916fc6075a6d618f2b03eaa0a24567d3139928ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id: PKGBUILD 157532 2012-04-28 22:21:55Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jan Jezek <honzin.jezek@gmail.com>
pkgname=tumbler
pkgver=0.1.25
pkgrel=1
pkgdesc="D-Bus service for applications to request thumbnails"
arch=('i686' 'x86_64')
url="http://git.xfce.org/xfce/tumbler/"
license=('GPL2' 'LGPL')
groups=('xfce4')
depends=('dbus-glib' 'gdk-pixbuf2')
makedepends=('intltool' 'ffmpegthumbnailer' 'gstreamer0.10' 'poppler-glib'
'libgsf' 'libopenraw' 'freetype2')
optdepends=('ffmpegthumbnailer: for video thumbnails'
'gstreamer0.10: for video thumbnails'
'poppler-glib: for PDF thumbnails'
'libgsf: for ODF thumbnails'
'libopenraw: for RAW thumbnails'
'freetype2: for font thumbnails')
options=('!libtool')
source=(http://archive.xfce.org/src/apps/$pkgname/0.1/$pkgname-$pkgver.tar.bz2)
sha256sums=('02d5de508d8c18692a25a832a9280c2043f6b7c90dd3fcbd87f5955337015546')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/xfce4 \
--disable-static \
--disable-debug
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
