blob: c496e4e61f67d3c83ddd65e5fff24a1a5784ceda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# $Id: PKGBUILD 169974 2012-10-30 22:59:38Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgname=udisks2
pkgver=2.0.0
pkgrel=1
pkgdesc="Disk Management Service, version 2"
arch=('i686' 'x86_64')
url="http://www.freedesktop.org/wiki/Software/udisks"
license=('GPL2')
depends=('glib2' 'udev' 'polkit' 'libatasmart' 'eject')
makedepends=('intltool' 'docbook-xsl' 'gobject-introspection')
optdepends=('parted: partition management'
'gptfdisk: GUID partition table support')
options=(!libtool)
source=(http://udisks.freedesktop.org/releases/udisks-$pkgver.tar.bz2)
sha256sums=('aa026a5a865688a2e9e430a389c7636c1a556d980539e4bd4a3f31dc5d4fe1eb')
build() {
cd "udisks-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--localstatedir=/var --disable-static
make
}
package() {
cd "udisks-$pkgver"
make DESTDIR="$pkgdir" install \
bash_completiondir=/usr/share/bash-completion/completions
}
|
