blob: 73f5b0deff0ee1edb36aec2fef2a398cac5dbeb7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# $Id: PKGBUILD 160375 2012-06-01 12:58:51Z dreisner $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
# Contributor: Martin Sandsmark <martin.sandsmark@kde.org>
pkgname=vlc
pkgver=2.0.1
pkgrel=2
pkgdesc="A multi-platform MPEG, VCD/DVD, and DivX player"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.videolan.org/vlc/"
license=('LGPL2.1' 'GPL2')
depends=('a52dec' 'libdvbpsi' 'libxpm' 'libdca' 'qt' 'libproxy'
'sdl_image' 'libdvdnav' 'libtiger' 'lua' 'libmatroska'
'zvbi' 'taglib' 'libmpcdec' 'ffmpeg' 'faad2' 'libupnp'
'libshout' 'libmad' 'libmpeg2' 'libmodplug' 'libass'
'xcb-util-keysyms' 'ttf-freefont')
makedepends=('live-media' 'libnotify' 'libbluray' 'flac' 'kdelibs'
'fluidsynth' 'libdc1394' 'libavc1394'
'libcaca' 'librsvg' 'portaudio' 'libgme' 'xosd'
'twolame' 'aalib' 'libmtp' 'libdvdcss'
'gnome-vfs' 'libgoom2' 'libtar' 'vcdimager')
[ "$CARCH" = "mips64el" ] || makedepends+=('lirc-utils' 'oss' 'projectm')
optdepends=('avahi: for service discovery using bonjour protocol'
'libnotify: for notification plugin'
'ncurses: for ncurses interface support'
'libdvdcss: for decoding encrypted DVDs')
[ "$CARCH" = "mips64el" ] || optdepends+=('lirc-utils: for lirc plugin')
optdepends+=('libavc1394: for devices using the 1394ta AV/C'
'libdc1394: for IEEE 1394 plugin'
'kdelibs: KDE Solid hardware integration')
[ "$CARCH" = "mips64el" ] || optdepends+=('libva-driver-intel: back-end for intel cards')
optdepends+=('libbluray: for Blu-Ray support'
'flac: for Free Lossless Audio Codec plugin')
[ "$CARCH" = "mips64el" ] || optdepends+=('oss: for OSS audio support')
optdepends+=('portaudio: for portaudio support'
'twolame: for TwoLAME mpeg2 encoder plugin')
[ "$CARCH" = "mips64el" ] || optdepends+=('projectm: for ProjectM visualisation plugin')
optdepends+=('libcaca: for colored ASCII art video output'
'libgme: for libgme plugin'
'librsvg: for SVG plugin'
'gnome-vfs: for GNOME Virtual File System support'
'libgoom2: for libgoom plugin'
'vcdimager: navigate VCD with libvcdinfo'
'xosd: for xosd support'
'aalib: for ASCII art plugin'
'libmtp: for MTP devices support'
'fluidsynth: for synthesizer MIDI FluidSynth'
'smbclient: for SMB access plugin')
conflicts=('vlc-plugin')
replaces=('vlc-plugin')
backup=('usr/share/vlc/lua/http/.hosts'
'usr/share/vlc/lua/http/dialogs/.hosts')
options=('!libtool' '!emptydirs')
install=vlc.install
source=("http://download.videolan.org/pub/videolan/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz")
md5sums=('5ad114755670e4881a2b35354e2f79bc')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i -e 's:truetype/freefont:TTF:g' modules/text_renderer/freetype.c
[ "$CARCH" = "mips64el" ] && extraconf="--disable-lirc"
./configure --prefix=/usr \
--disable-rpath \
--enable-oss \
--enable-faad \
--enable-nls \
--enable-lirc \
--enable-pvr \
--enable-ncurses \
--enable-realrtsp \
--enable-xosd \
--enable-aa \
--enable-vcdx \
$extraconf
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
for res in 16 32 48 128; do
install -D -m644 "${srcdir}/vlc-${pkgver}/share/icons/${res}x${res}/vlc.png" \
"${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
done
}
|
