blob: 80e79e08bdf3478c56bc44b42fa341d92a01e013 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 106210 2011-01-15 11:51:10Z bisson $
# Contributor: dorphell <dorphell@archlinux.org>
pkgname=w3m
pkgver=0.5.3
pkgrel=1
pkgdesc='Text-based Web browser, as well as pager'
arch=('i686' 'x86_64')
url='http://w3m.sourceforge.net/'
license=('custom')
depends=('openssl' 'gc' 'ncurses' 'zlib')
makedepends=('imlib2')
optdepends=('imlib2: for graphics support')
source=("http://downloads.sourceforge.net/sourceforge/w3m/$pkgname-$pkgver.tar.gz")
sha1sums=('444b6c8cf7094ee95f8e9de96b37f814b9d83237')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure \
--prefix=/usr \
--libexecdir=/usr/lib \
--enable-image=x11,fb \
--with-imagelib=imlib2 \
--with-termlib=ncurses \
--disable-w3mmailer \
--disable-mouse
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -d "$pkgdir"/usr/share/{doc,licenses}/"$pkgname"
find doc/* | grep -v CVS | xargs -i install "{}" "$pkgdir/usr/share/doc/$pkgname/"
ln -s "../../doc/$pkgname/README" "$pkgdir/usr/share/licenses/$pkgname/"
}
|
