extra/wpa_supplicant_gui/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# $Id: PKGBUILD 162910 2012-07-03 19:17:02Z dreisner $
# Maintainer: Thomas Bächler <thomas@archlinux.org>

pkgname=wpa_supplicant_gui
pkgver=1.0
pkgrel=1
pkgdesc="A Qt frontend to wpa_supplicant"
url="http://hostap.epitest.fi/wpa_supplicant"
arch=('i686' 'x86_64')
depends=('qt' "wpa_supplicant=$pkgver")
license=('GPL')
source=("http://hostap.epitest.fi/releases/wpa_supplicant-$pkgver.tar.gz"
        compile-fix.patch)
sha256sums=('91d41d473a5aafa2e25dd6577ebda975c4d4a3188850a53e31feaf7c04482b9c'
            '044be1032faf93c5f0abf22d7ae77dc0d1d1fef0c2c30646d54950b86601709f')

build() {
  cd wpa_supplicant-${pkgver}
  patch -p1 <../compile-fix.patch
  cd wpa_supplicant/wpa_gui-qt4
  qmake
  make
}

package() {
  cd "${srcdir}/wpa_supplicant-${pkgver}/wpa_supplicant/wpa_gui-qt4"
  install -Dm755 wpa_gui "${pkgdir}/usr/sbin/wpa_gui"
  install -Dm644 icons/wpa_gui.svg "${pkgdir}/usr/share/pixmaps/wpa_gui.svg"
  install -Dm644 wpa_gui.desktop "${pkgdir}/usr/share/applications/wpa_gui.desktop"
  install -Dm644 "${srcdir}/wpa_supplicant-${pkgver}/wpa_supplicant/doc/docbook/wpa_gui.8" \
     "${pkgdir}/usr/share/man/man8/wpa_gui.8"
}