blob: be600b6005b30822f6376a371e6a886a619b1475 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 119109 2011-04-10 23:04:52Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Contributor: Andrew Wright <andreww@photism.org>
pkgname=wxpython
pkgver=2.8.11.0
pkgrel=3
pkgdesc="A wxWidgets GUI toolkit for Python"
arch=('i686' 'x86_64')
license=('custom:wxWindows')
url="http://www.wxpython.org"
depends=('wxgtk' 'python2')
makedepends=('mesa')
source=(http://downloads.sourceforge.net/wxpython/wxPython-src-${pkgver}.tar.bz2 editra-aui.diff)
md5sums=('63f73aae49e530852db56a31b57529fa'
'06c637c34c1570d8c82b870ce19c0622')
sha1sums=('18982edc236a1d87e4eef018928358c925aa5b17'
'077fe341bf8822647934d6b1ea82ce9b0adbf93a')
build() {
cd "${srcdir}/wxPython-src-${pkgver}"
patch -p1 < ../editra-aui.diff
./configure --prefix=/usr --libdir=/usr/lib --with-gtk=2 --with-opengl --enable-unicode \
--enable-graphics_ctx --with-gnomeprint --disable-optimize --enable-mediactrl \
--with-libpng=sys --with-libxpm=sys --with-libjpeg=sys --with-libtiff=sys
cd "${srcdir}/wxPython-src-${pkgver}/wxPython"
python2 setup.py WXPORT=gtk2 UNICODE=1 build
}
package() {
cd "${srcdir}/wxPython-src-${pkgver}/wxPython"
python2 setup.py WXPORT=gtk2 UNICODE=1 install --root="${pkgdir}"
install -D -m644 ../docs/licence.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
