blob: 5297fc185ac1dd716ffff927f0770a7c802fe130 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 194429 2013-09-16 10:38:03Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: tobias <tobias funnychar archlinux.org>
pkgname=xfce4-session
pkgver=4.10.1
pkgrel=3
pkgdesc="A session manager for Xfce"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.xfce.org/"
license=('GPL2')
groups=('xfce4')
depends=('libxfce4ui' 'libwnck' 'libsm' 'xorg-iceauth' 'upower' 'xorg-xinit'
'xorg-xrdb' 'hicolor-icon-theme')
makedepends=('intltool' 'xfce4-dev-tools')
optdepends=('gnome-keyring: for keyring support when GNOME compatibility is enabled'
'xscreensaver: for locking screen with xflock4'
'gnome-screensaver: for locking screen with xflock4'
'xlockmore: for locking screen with xflock4')
replaces=('xfce-utils')
options=('!libtool')
install=$pkgname.install
source=(http://archive.xfce.org/src/xfce/$pkgname/4.10/$pkgname-$pkgver.tar.bz2
xfce4-session-4.10.1-logind-support-for-suspend-hibernate.patch)
sha256sums=('0154fabdc398798c3445374ccc52a2f5bcb2d867fc94bc54114395b24f9cfc83'
'1fc10b6495624ddfb9e18419c835f7b929ad738c602a64ee7aab8327d3aac981')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
# Use logind interfaces for suspend and hibernate
# https://bugzilla.xfce.org/show_bug.cgi?id=9952
patch -Np1 -i "$srcdir/xfce4-session-4.10.1-logind-support-for-suspend-hibernate.patch"
xdt-autogen
}
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/xfce4 \
--localstatedir=/var \
--disable-static \
--disable-debug
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
