blob: 2a95b22f55c9cd7eab49db39c703c5331b945225 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 169968 2012-10-30 22:59:13Z heftig $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: tobias <tobias funnychar archlinux.org>
pkgname=xfce4-session
pkgver=4.10.0
pkgrel=6
pkgdesc="A session manager for Xfce"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.xfce.org/"
license=('GPL2')
groups=('xfce4')
depends=('libxfce4ui' 'libwnck' 'libsm' 'xorg-iceauth' 'upower' 'xorg-xinit'
'hicolor-icon-theme')
makedepends=('intltool' 'xfce4-dev-tools')
optdepends=('gnome-keyring: for keyring support when GNOME compatibility is enabled'
'xscreensaver: for locking screen with xflock4'
'gnome-screensaver: for locking screen with xflock4'
'xlockmore: for locking screen with xflock4')
replaces=('xfce-utils')
options=('!libtool')
install=$pkgname.install
source=(http://archive.xfce.org/src/xfce/$pkgname/4.10/$pkgname-$pkgver.tar.bz2
xfce4-session-4.10.0-add-systemd-support.patch)
sha256sums=('bb8aa9a74c3d382840596fb4875144d66c7f3f47c8e9ee81d31e3428a72c46ce'
'ffae61c48a4bd0cb51d422cb93f2de9567abaf29085370c455ef349b6a10234b')
build() {
cd "$srcdir/$pkgname-$pkgver"
# https://bugzilla.xfce.org/show_bug.cgi?id=8729
patch -Np1 -i "$srcdir/xfce4-session-4.10.0-add-systemd-support.patch"
xdt-autogen
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/xfce4 \
--localstatedir=/var \
--disable-static \
--disable-debug
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
