blob: 2bbf9576323109d432bd5218faf41fee38fea617 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 153046 2012-03-12 00:28:07Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-control-center
pkgver=3.3.91
pkgrel=2
pkgdesc="The Control Center for GNOME"
arch=('i686' 'x86_64')
depends=('gtk3' 'gsettings-desktop-schemas' 'gnome-menus' 'gnome-desktop' 'gnome-settings-daemon'
'upower' 'libgtop' 'cups-pk-helper' 'accountsservice' 'sound-theme-freedesktop'
'gnome-online-accounts' 'network-manager-applet' 'gnome-bluetooth' 'libsocialweb')
optdepends=('mesa-demos: provides glxinfo for graphics information'
'apg: adds password generation for user accounts'
'gnome-color-manager: for color management tasks'
'cheese: take account photos via webcam')
makedepends=('gnome-doc-utils' 'intltool' 'gnome-common' 'cheese')
url="http://www.gnome.org"
groups=('gnome')
install=gnome-control-center.install
license=('GPL')
options=('!libtool' '!emptydirs')
source=(http://download.gnome.org/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz
systemd-fallback.patch)
sha256sums=('6a08f50d6760ef62e567aa1240fca054cc33e8aac37a4fb318cfb4d7b611abfb'
'5fa706de582228df36dfc13eb37470e543b2f228f1fc4ad27e35a781a8779b39')
build() {
cd ${pkgname}-${pkgver}
patch -Np1 -i ../systemd-fallback.patch
gnome-autogen.sh --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--enable-systemd --with-libsocialweb \
--disable-update-mimedb
#https://bugzilla.gnome.org/show_bug.cgi?id=656229
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
}
|
