blob: cce30bd0ad77f3d8762688fc7549b773af246cd7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 167161 2012-09-26 17:29:17Z jgc $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=gnome-games
pkgver=3.6.0.2
pkgrel=1
pkgdesc="Some Games for GNOME"
arch=('i686' 'x86_64')
license=('GPL')
depends=('desktop-file-utils' 'libcanberra' 'clutter-gtk' 'hicolor-icon-theme' 'librsvg' 'python2-gobject' 'dconf')
makedepends=('yelp-tools' 'intltool' 'gobject-introspection' 'vala')
options=('!emptydirs' '!libtool')
install=gnome-games.install
url="http://www.gnome.org"
groups=('gnome-extra')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:3}/$pkgname-$pkgver.tar.xz)
sha256sums=('353b416dd86e2b6f323d28011c9b478b9848fabc5686a2e01bbd35e36402ed2c')
build() {
cd $pkgname-$pkgver
PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static --disable-schemas-compile \
--with-scores-user=root --with-scores-group=games \
--enable-introspection=yes
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
# Remove all scores, we generate them from postinstall
rm -rf "$pkgdir/var"
sed -i 's_#! /usr/bin/env python_#!/usr/bin/env python2_' "$pkgdir/usr/bin/gnome-sudoku"
}
|
