blob: 6d5c0971b453042c848a927243d928885c456542 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 138558 2011-09-27 10:50:44Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=libgweather
pkgver=3.2.0
pkgrel=1
pkgdesc="Provides access to weather information from the net"
arch=('i686' 'x86_64')
license=('LGPL')
depends=('gconf' 'libsoup-gnome' 'gnome-icon-theme')
makedepends=('pkgconfig' 'intltool' 'gtk-doc' 'gobject-introspection' 'gnome-common')
options=('!libtool' '!emptydirs')
url="http://www.gnome.org/"
install=libgweather.install
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz
gettext-not-xml.patch)
sha256sums=('7fdae4aad787759ed0d0124d66991311a24c8c9a3c9a46c56f62e4cc4575aea9'
'5b6bf182294b8974a89492237d98b60678b83efcf31de8a0ca1bebd90f3356a3')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -Np1 -i "${srcdir}/gettext-not-xml.patch"
gtkdocize
autoreconf -fi
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static \
--enable-locations-compression
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install
install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain libgweather ${pkgdir}/etc/gconf/schemas/*.schemas
rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
}
|
