blob: 57c8f869384fbef857719ccbc8408c8ba5bd8c6f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# $Id: PKGBUILD 138263 2011-09-19 18:00:23Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=pygobject
pkgname=(python-gobject python2-gobject pygobject-devel)
pkgver=3.0.0
pkgrel=1
arch=('i686' 'x86_64')
url="https://live.gnome.org/PyGObject"
license=('LGPL')
makedepends=('python' 'python2' 'python-cairo' 'python2-cairo' 'gobject-introspection')
source=(http://ftp.gnome.org/pub/gnome/sources/${pkgbase}/${pkgver%.*}/${pkgbase}-${pkgver}.tar.xz)
options=('!libtool')
sha256sums=('ef6735792b0d44287126a6a3b181c85559849063d770506fe06848adb87ce815')
build() {
cd "${srcdir}"
cp -a "${pkgbase}-${pkgver}" python2-build
mkdir devel
(
cd python2-build
export PYTHON=/usr/bin/python2
./configure --prefix=/usr
make
)
(
cd "${pkgbase}-${pkgver}"
./configure --prefix=/usr
make
)
}
package_python-gobject() {
pkgdesc="Python 3 bindings for GObject"
depends=('gobject-introspection' 'python-cairo' "pygobject-devel=${pkgver}")
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -r "${pkgdir}"/usr/{include,lib/pkgconfig}
}
package_python2-gobject() {
pkgdesc="Python 2 bindings for GObject"
depends=('gobject-introspection' 'python2-cairo' "pygobject-devel=${pkgver}")
cd "${srcdir}/python2-build"
make DESTDIR="${pkgdir}" install
mv "${pkgdir}"/usr/{include,lib/pkgconfig} "${srcdir}/devel"
}
package_pygobject-devel() {
pkgdesc="Development files for the pygobject bindings"
cd "${srcdir}/devel"
mkdir -p "${pkgdir}"/usr/{include,lib}
mv include "${pkgdir}/usr/"
mv pkgconfig "${pkgdir}/usr/lib/"
}
|
